vim-highlight/plugin/hightlight.vim

" ==============================================================================
" File:            highlight.vim
" Maintainer:      Joshua Potter <jrpotter2112@gmail.com>
"
" ==============================================================================

if exists('g:loaded_highlight_registry')
  finish
endif
let g:loaded_highlight_registry = 1


" GLOBAL VARIABLES:
" ==============================================================================

" g:highlight_registry :: { String : { String : String } } {{{2
" ------------------------------------------------------------------------------
" The following dictionary corresponds to registers 0-9 and their respective
" syntax attributes. Adjust this to set the properties for a given highlight
" group. Allowed keys in the nested dictionary are listed in *synIDattr*, except
" for the 'name' attribute. Unrecognized keys are simply ignored. Only 'cterm'
" related attributes are supported (that is, gui specific attributes are not
" supported).
"
" In addition, can also include a key of 'group' in the nested dictionary to
" indicate which highlight group to default a property to. By default, this
" group is 'Search'. Thus, key '0' could also be written as:
" { 'fg' : 'Yellow', 'group' : 'Search', 'bold': '0' }.
"
" TODO(jrpotter): Consider adding support for GUI and term?

if !exists('g:highlight_registry')
  function! s:InitializeHighlightRegistry()
    let g:highlight_registry = {}
    let l:colors = [ 'Yellow', 'Blue', 'Red', 'Magenta', 'Green', 'Cyan',
                   \ 'DarkYellow', 'White', 'Gray', 'Black' ]
    let l:index = 0
    while l:index < len(l:colors)
      let g:highlight_registry[string(l:index)] =
            \{ 'fg' : l:colors[l:index], 'bg' : 'none', 'bold' : '1' }
      let l:index = l:index + 1
    endwhile
  endfunction
  call s:InitializeHighlightRegistry()
endif


" g:persist_unnamed_register :: Boolean {{{2
" ------------------------------------------------------------------------------
" Determines how to manage the unnamed register '"'. If set to false, we regard
" the unnamed register to implicitly imply use of the last activated register.

if !exists('g:persist_unnamed_register')
  let g:persist_unnamed_register = 0
endif


" FUNCTION: ExpandRegister(reg) {{{1
" ==============================================================================
" Convenience method to determine which register is being currently used.
" The unnamed register defaults to the last used register to avoid having to
" constantly prefix registration. This can be changed by setting the value of
" g:persist_unnamed_register to 1.

function! s:ExpandRegister(reg)
  if !g:persist_unnamed_register && a:reg ==# '"'
    return s:active_register
  endif
  return a:reg
endfunction


" FUNCTION: ExpandFlag(flag) {{{1
" ==============================================================================
" Convenience method used to make the mappings in plugin/highlight.vim a bit
" easier to read through. The passed flag can be:
"
" c: Indicates the current word, with word boundary.
" g: Indicates the current word, without word boundary.
" v: Indicates the current visual selection.
"
" Throws an error otherwise.

function! s:ExpandFlag(flag) abort
  if a:flag ==# 'c'
    return '\<' . expand('<cword>') . '\>'
  elseif a:flag ==# 'g'
    return expand('<cword>')
  elseif a:flag ==# 'v'
    return highlight#get_visual_selection()
  endif
  throw 'Could not expand passed flag: ' . a:flag
endfunction


" MAPPINGS: {{{1
" ==============================================================================

" Append Searches
noremap <Plug>HRegistry_AppendToSearch
    \ :call highlight#append_to_search(s:ExpandRegister(v:register), s:ExpandFlag('c'))<Bar>
    \  call highlight#count_pattern(s:ExpandFlag('c'))<CR>
noremap <Plug>HRegistry_GAppendToSearch
    \ :call highlight#append_to_search(s:ExpandRegister(v:register), s:ExpandFlag('g'))<Bar>
    \  call highlight#count_pattern(s:ExpandFlag('g'))<CR>
noremap <Plug>HRegistry_VisualAppendToSearch
    \ :call highlight#append_to_search(s:ExpandRegister(v:register), s:ExpandFlag('v'))<Bar>
    \  call highlight#count_pattern(s:ExpandFlag('v'))<CR>

" Remove Searches
noremap <Plug>HRegistry_RemoveFromSearch
    \ :call highlight#remove_from_search(s:ExpandRegister(v:register), s:ExpandFlag('c'))<CR>
noremap <Plug>HRegistry_VisualRemoveFromSearch
    \ :call highlight#remove_from_search(s:ExpandRegister(v:register), s:ExpandFlag('v'))<CR>

" Other Modifications
noremap <Plug>HRegistry_ClearRegister
    \ :call highlight#clear_register(s:ExpandRegister(v:register))<Bar>
    \  call highlight#activate_register(s:ExpandRegister(v:register))<CR>
noremap <Plug>HRegistry_ActivateRegister
    \ :call highlight#activate_register(s:ExpandRegister(v:register))<CR>
noremap <Plug>HRegistry_CountLastSeen
    \ :call highlight#count_pattern(s:ExpandFlag('c'))<CR>

" Normal Mappings
nmap <silent>  & <Plug>HRegistry_AppendToSearch
nmap <silent> g& <Plug>HRegistry_GAppendToSearch
nmap <silent> y& <Plug>HRegistry_ActivateRegister
nmap <silent> d& <Plug>HRegistry_RemoveFromSearch
nmap <silent> c& <Plug>HRegistry_ClearRegister

nmap <silent>  * :silent norm! *<CR>&
nmap <silent> g* :silent norm! *<CR>g&

nmap <silent>  # :silent norm! #<CR>&
nmap <silent> g# :silent norm! #<CR>g&

" Visual Mappings
vmap <silent>  & <Plug>HRegistry_VisualAppendToSearch'<
vmap <silent> d& <Plug>HRegistry_VisualRemoveFromSearch'<
vmap <silent>  * &n<Plug>HRegistry_CountLastSeen
vmap <silent>  # &N<Plug>HRegistry_CountLastSeen


" PROCEDURE: Commands {{1
" ==============================================================================

command ResetHighlightRegistry :call highlight#reset()


" PROCEDURE: Initialize {{{1
" ==============================================================================

call highlight#reset()